Tommi Pirinen: suomen kielen verbien ns. avoleksikko

Työn rajaukset

...

! Suomen verbit kotuksen taivutustaulukon mukaan
! varhainen xfst-proto

! Verbiluokat symboleina
! (jatkuu)
! Ajat, tavat
! verbin persoonamuotojen symbolit
! Kliitit
! Sointuvokaalit aä, oö, uy, astevaihteluklusiilit k, p, t, g, b, d, ja\
! vokaalin pidentymä (tai toisto illatiivin tunnuksessa)\
! vaihteleva laveneva diftongi? N joka assimiloituu vasemmalle (nut-partisiipi\
! ja potentiaali).
Multichar_Symbols +V52 +V53 +V54 +V55 +V56 +V57 +V58 +V59 +V60
      +V61 +V62 +V63 +V64 +V65 +V66 +V67 +V68 +V69 +V70 +V71 +V72
      +Pres +Past +Indv +Potn +Cond +Impv
      +1P +2P +3P +Sg +Pl +4P +Act +Pss 
      +ClitPA +ClitS
      ^k ^p ^t ^g ^b ^d ^v ^uo ^yö ^ie ^n


LEXICON Root
        Verbit ;

LEXICON Verbit
sanoa:sano      V52 ; ! sanoa
muistaa:muist   V53 ; ! muistaa
huutaa:huu      V54 ; ! huutaa
soutaa:sou      V55 ; ! soutaa
kaivaa:kaiv      V56 ; ! kaivaa
saartaa:saar   V57 ; ! saartaa
laskea:lask      V58 ; ! laskea
tuntea:tun      V59 ; ! tuntea
lähteä:lä      V60 ; ! lähteä
sallia:sall      V61 ; ! sallia
voida:vo      V62 ; ! voida
saada:saa      V63 ; ! saada
juoda:j^uo      V64 ; ! juoda
syödä:s^yö      V64 ; ! syödä
viedä:v^ie      V64 ; ! viedä
käydä:kä      V65 ; ! käydä
rohkaista:rohkai   V66 ; ! rohkaista
tulla:tul      V67 ; ! tulla
tupakoida:tupako   V68 ; ! tupakoida
valita:vali      V69 ; ! valita
juosta:juo      V70 ; ! juosta
nähdä:nä      V71 ; ! nähdä
vanheta:vanhe   V72 ; ! vanheta
salata:sala      V73 ; ! salata
katketa:katke   V74 ; ! katketa
selvitä:selvi   V75 ; ! selvitä
taitaa:tai      V76 ; ! taitaa
kumajaa:kumaj   V77 ; ! kumajaa
kaikaa:kaika   V78 ; ! kaikaa

! sanoa
LEXICON V52
+V52:0      AjatJaTavat ;

! muistaa
LEXICON V53
+V53:^a      PreesensJaTavat ; ! indikatiivin preesens
+V53+Past:i   Persoonat ; ! preteriti

! huutaa
LEXICON V54
+V54:^t^a      PreesensJaTavat ; ! indikatiivin preesens
+V54+Past:si   Persoonat ; ! preteriti

! soutaa
LEXICON V55
+V55:^t^a      PreesensJaTavat ; ! indikatiivin preesens
+V55+Past:^ti   Persoonat ; ! preteriti 1
+V55+Past:si   Persoonat ; ! preteriti 2

! kaivaa
LEXICON V56
+V56:^a      PreesensJaTavat; ! indikatiivin preesens
+V56:^o      Preteritivartalo; ! preteriti

! saartaa
LEXICON V57
+V57:^t^a   PreesensJaTavat; ! indikatiivin preesens
+V57+Past:si      Persoonat; ! preteriti 1
+V57+Past:^t^oi      Persoonat; ! preteriti 2

! laskea
LEXICON V58
+V58:e      PreesensImpvPotn; ! indikatiivin preesens
+V58:0      PreteritiJaKonditionaali; ! preteriti

! tuntea
LEXICON V59
+V59:^te   PreesensVartalo; ! indikatiivin preesens
+V59:te      Tavat;
+V59:s      Preteritivartalo; ! preteriti
+V59:^t      Konditionaalivartalo; ! konditionaali

! lähteä
LEXICON V60
+V60:h^te      PreesensJaTavat; ! indikatiivin preesens
+V60+Past:h^ti      Persoonat; ! preteriti 1
+V60+Past:ksi      Persoonat; ! preteriti 2

! sallia
LEXICON V61
+V61:i      PreesensImpvPotn; ! indikatiivin preesens
+V61:0      PreteritiJaKonditionaali; ! preteriti

! voida
LEXICON V62
+V62:i      PreesensImpvPotn; ! indikatiivin preesens
+V62:0      PreteritiJaKonditionaali; ! preteriti

! saada
LEXICON V63
+V63:^v      PreesensJaTavat;
+V63:0      PreteritiJaKonditionaali;

! juoda
LEXICON V64
+V64+Indv+Pres:0   Persoonat; ! indikatiivin preesens
+V64+Past:i      Persoonat; ! preteriti
+V64+Cond:isi   Persoonat;   ! konditionaali
+V64+Potn:ne   Persoonat;   ! potentiaali

! käydä
LEXICON V65
+V65+Indv+Pres:y      Persoonat;   ! indikatiivin preesens
+V65+Past:vi   Persoonat;   ! preteriti
+V65+Cond:visi   Persoonat;   ! konditionaali
+V65+Potn:yne   Persoonat;   ! potentiaali

! rohkaista
LEXICON V66
+V66+Indv+Pres:se      Persoonat; 
+V66+Past:si   Persoonat; ! preteriti
+V66:s      Tavat;

! tulla
LEXICON V67
+V67+Indv+Pres:e   Persoonat;
+V67+Past:i      Persoonat;
+V67:0      Tavat;

! tupakoida
LEXICON V68
+V68+Indv+Pres:i   Persoonat;
+V68+Indv+Pres:itse   Persoonat;
+V68+Past:i      Persoonat;
+V68+Past:itsi   Persoonat;
+V68:i         Tavat;
+V68+Cond:itsisi   Persoonat;

! valita
LEXICON V69
+V69+Indv+Pres:tse   Persoonat;
+V69+Past:tsi      Persoonat;

! juosta
LEXICON V70
+V70+Indv+Pres:kse      Persoonat;
+V70+Past:ksi      Persoonat;

! nähdä
LEXICON V71
+V71+Indv+Pres:^ke      Persoonat;
+V71+Past:^ki      Persoonat;

! vanheta
LEXICON V72
+V72+Indv+Pres:ne   Persoonat;
+V72+Past:ni   Persoonat;

! salata
LEXICON V73
+V73+Indv+Pres:^v   Persoonat;
+V73+Past:si   Persoonat;

! katketa
LEXICON V74
+V74+Indv+Pres:^a   Persoonat;
+V74+Past:si   Persoonat;

! selvitä
LEXICON V75
+V75+Indv+Pres:^a   Persoonat;
+V75+Past:si   Persoonat;

! taitaa
LEXICON V76
+V76+Indv+Pres:^t^a   Persoonat;
+V76+Past:si   Persoonat;

! kumajaa
LEXICON V77
+V77+InfA+Lat+Sg:^a   #;
+V77+Indv+Pres:^a   Persoonat;
+V77+Past:i         Persoonat;
+V77+Cond:^aisi      Persoonat;

! kaikaa
LEXICON V78
+V78+InfA+Lat+Sg:^a      #;
+V78+Indv+Pres+Sg+3:^a   #;
+V78+Cond:isi         Persoonat;


! mallien taivutusleksikot
! Kotuksen mallisanan A-infinitiivivartalo (1. rivi)
LEXICON Infinitiivivartalo
#;

! Kotuksen mallisanan preesensvartalo (2. rivi)
LEXICON Preesensvartalo
+Ind+Pres:0   Persoonat;

! Kotuksen mallisanan preteritivartalo (3. rivi)
LEXICON Preteritivartalo
+Past:i   Persoonat;

! Kotuksen mallisanan konditionaalivartalo (4. rivi)
LEXICON Konditionaalivartalo
+Cond:isi   Persoonat;

! Kotuksen mallisanan potentiaalivartalo (5. rivi)
LEXICON Potentiaalivartalo
+Potn:^ne   Persoonat;

! Kotuksen mallisanan imperatiivivartalo (6. rivi)
LEXICON Imperatiivivartalo
      Imperatiivit;

! Kotuksen mallisanan NUT-partisiippivartalo (7. rivi)
LEXICON Partisiippivartalo
#;
! N47; ! NUT-partisiippi on luokan 47 substantiiviadjektiivi

! Kotuksen mallisanan partisiippivartalo (8. rivi)
LEXICON Passiivivartalo
   #;
! Kotuksen malliluokkien yhdistelmiä ja väännelmiä:

! Sama preesens- ja preteritivartalo
LEXICON Ajat
      Preesensvartalo; ! indikatiivin preesens
      Preteritivartalo; ! preteriti

! Sama konditionaali-, potentiaali- ja imperatiivivartalo
LEXICON Tavat
      Konditionaalivartalo; ! konditionaali
      Potentiaalivartalo; ! potentiaali
      Imperatiivivartalo;

! Sama preesens-, konditionaali-, potentiaali- ja imperatiivivartalo
LEXICON PreesensJaTavat
      Preesensvartalo; ! indikatiivin preesens
      Tavat;

! Sama preesens-, imperatiivi- ja potentiaalivartalo
LEXICON PreesensImpvPotn
      Preesensvartalo;
      Imperatiivivartalo;
      Potentiaalivartalo;

! Sama preteriti- ja konditionaalivartalo
LEXICON PreteritiJaKonditionaali
      Preteritivartalo;
      Konditionaalivartalo;

! Sama preesens-, preteriti-, konditionaali-, potentiaali- ja imperatiivivartalo
LEXICON AjatJaTavat
      Ajat;
      Tavat;

LEXICON Imperatiivit
+Impv+2P+Sg:k^o^on      Kliitit; ! Yksikön toisen imperatiivi 
+Impv+3P+Pl:k^o^ot      Kliitit; ! Yksikön kolmannen imperatiivi
+Impv+1P+Pl:k^a^amme   Kliitit; ! Monikon ensimmäisen imperatiivi
+Impv+2P+Pl:k^a^a      Kliitit; ! Monikon toisen imperatiivi

LEXICON Persoonat
+1P+Sg:n   Kliitit; ! Yksikön ensimmäinen
+2P+Sg:t   Kliitit; ! Yksikön toinen
+3P+Sg:^v   Kliitit; ! Yksikön kolmas
+1P+Pl:mme   Kliitit; ! Monikon ensimmäinen
+2P+Pl:tte   Kliitit; ! Monikon toinen
+3P+Pl:v^at   Kliitit; ! Monikon kolmas

LEXICON Kliitit
+ClitPA:p^a         #;
+ClitPA+ClitS:p^as   #;
+ClitKO:k^o         #;
+ClitKIN:kin      #;
               #; ! Tyhjä kohta koska kliitti ei ole pakollinen

! Koskenniemi(1983) jatkeet:
LEXICON V0
+Pres+Act   1-3-N;
+Impv+Act+Sg+2   K01;
!+minen      Nxxx;
!+Act+InfMA      /S;
!+Act+PcpMA      /A;
!+Act+PcpVA      /A;
!+Act+InfMA+Abe+Sg+ton Nxxx;

LEXICON V1
+Past+Act:i      1-3;

LEXICON V2
+Cond+Act:isi   1-3-N;

! Muutokset: 
! koot # -> K (antautkootpa)
! ko # -> K (älkääpä luulkokaan)
LEXICON V3
+Potn+Act:^ne      1-3-N;
+Impv+Act+Sg+3:k^o^on   K;
+Impv+Act+Pl+1:k^a^amme   K;
+Impv+Act+Pl+2:k^a^a   K01;
+Impv+Act+Pl+2:k^a^atte   #;
+Impv+Act+Pl+3:k^o^ot   K;
+Impv+Act+Neg:k^o   K;
+Pss+Pres:^d^a   4-N;
+Pss+Past+4:^ztiin   K;
+Pss+Cond:^zt^aisi   4-N;
+Pss+Potn:^zt^ane   4-N;
+Pss+Impv:^zt^ak^o   4-N;
+InfA+Lat:^d^a      K;
+InfA+Tra:^d^akse   P1;
+InfE+Ine:^dess^a   P;
+InfE+Ins:^den   K;
+Pss+InfE+Ine:^zt^aess^a   K;
+Pss+InfMA+Ins:^zt^am^an   K;
+Pss+PcpVA:^zt^av^a   Nxx;
+Act+PcpNUT:n^ut   Nxx;
+Pss+PcpNUT:^z^t^u   Nxx;

LEXICON Sg1-Pl3
+Sg+1:n   K;
+Sg+2:t   K;
+Sg+3:^v   K;
+Pl+1:mme   K;
+Pl+2:tte   K;
+Pl+3:v^at   K;

LEXICON Neg
+Neg   K;

LEXICON Pe4
+4:^vn   K;

LEXICON 1-3-N
   Sg1-Pl3;
   Neg;

LEXICON 1-3
   Sg1-Pl3;

LEXICON 4-N
   Pe4;
   Neg;

LEXICON /V
   V0;
   V1;
   V2;
   V3;

LEXICON V012
   V0;
   V1;
   V2;

LEXICON V02
   V0;
   V2;

LEXICON V023
   V0;
   V2;
   V3;

LEXICON V03
   V0;
   V3;

LEXICON V12
   V1;
   V2;

LEXICON V123
   V1;
   V2;
   V3;

LEXICON V23
   V2;
   V3;





! vim: set ft=xfst; tabstop=4; fileencoding=latin1:

Luennoijan kommentteja

  • 14.2.: Verbit on ehkä helpompi saada järjestykseen ja hallintaan, jos ne hahmottaa tiettyjen vartaloiden avulla. Niille päätteet ovat aika lailla vakinaiset. Verbeillä kun ei ole aitoa pääteallomorfiaa vaan ainoastaan lähinnä vartaloiden muodostuksen ongelmia. (1. infinitiivillä toki on ta/a -vaihtelu, mutta niistäkin vain toinen käy. Jotakin morfofonologiaa myös päätteiden yhteydessä, esim. kuol+ta = kuolla.)
    • V0 = vahva preesensvartalo, joka saadaan monikon kolmannesta persoonasta pudottamalla vat/vät pois, siis esim. erkanevat tuottaa preesensvartalon erkane. Tästä vartalosta tulee muitakin muotoja, esim. infinitiivejä ja partisiippeja (sekä johdoksia).
    • V1 = imperfektivartalo, joka tulee samalla tavalla imperfektistä, siis esim. haukkasivat tuottaa imperfektivartalon haukkasi ja sousivat, soutivat tuottaa vartalot sousi ja souti.
    • V2 = konditionaalivartalo, joka tulee samalla tavalla konditionaalista, siis esim. soutaisivat tuottaa soutaisi.
    • V3 = infinitiivivartalo, jonka saa imperatiivista, esim. hakatkoon tuottaan hakat ja tulkoon vartalon tul. Tästä vartalosta tulee muutakin, mm. potentiaalin muodot.

Käytettävissä on nyt:

  • Kotuksen vartalot alileksikkoina (7) kuten mainittu kainossa
    1. Infinitiivivartalo
    2. Preesensvartalo
    3. Preteritivartalo
    4. Konditionaalivartalo
    5. Potentiaalivartalo
    6. Imperatiivivartalo
    7. Partisiippivartalo
  • Kimmon vartalot alileksikkoina (5) kuten mainittu väitöskirjassa Two-level morphology: ... ... (1983) ja tuossa yllä.

-- TommiPirinen - 19 Mar 2007

Topic revision: r3 - 2007-03-19 - TommiPirinen
 
This site is powered by the TWiki collaboration platform Powered by PerlCopyright © 2008-2018 by the contributing authors. All material on this collaboration platform is the property of the contributing authors.
Ideas, requests, problems regarding TWiki? Send feedback